Neues Inventar Problem

Diese Seite verwendet Cookies. Durch die Nutzung unserer Seite erklären Sie sich damit einverstanden, dass wir Cookies setzen. Weitere Informationen

  • Neues Inventar Problem

    Mein Inventar ist recht besonders aufgebaut. Im Prinzip ist fast das ganze Inventar mit seinen Boxen ein Sprite. Dann habe ich ein Objekt obj_invScope, mit dem ich durch das Inventar navigieren kann. Dabei wird mit jedem bspw. vk_up die y Position um -80 verändert, bei jedem bspw. vk_right wird x um +100 verändert. Dadurch sieht es so aus, als würde das Scope immer exakt von Kasten zu Kasten springen.
    Ich habe sogar einen switch, der für die genaue x und y Position die Variable box = 0 verändert.

    GML-Quellcode

    1. switch (box)
    2. {
    3. case 1:
    4. x = 88 && y = 136;
    5. box = 1;
    6. break;
    7. case 2:
    8. x = 188 && y = 136;
    9. box = 2;
    10. break;
    11. case 3:
    12. x = 288 && y = 136;
    13. box = 3;
    14. break;
    15. case 4:
    16. x = 388 && y = 136;
    17. box = 4;
    18. break;
    19. case 5:
    20. x = 88 && y = 216;
    21. box = 5;
    22. break;
    23. case 6:
    24. x = 188 && y = 216;
    25. box = 6;
    26. break;
    27. case 7:
    28. x = 288 && y = 216;
    29. box = 7;
    30. break;
    31. case 8:
    32. x = 388 && y = 216;
    33. box = 8;
    34. break;
    35. case 9:
    36. x = 88 && y = 296;
    37. box = 9;
    38. break;
    39. case 10:
    40. x = 188 && y = 296;
    41. box = 10;
    42. break;
    43. case 11:
    44. x = 288 && y = 296;
    45. box = 11;
    46. break;
    47. case 12:
    48. x = 388 && y = 296;
    49. box = 12;
    50. break;
    51. }
    Alles anzeigen


    Nun kollidiere ich als Player mit meinem obj_knife, im Inventar wird dann auf x = 88 und y = 136 das Objekt obj_invKnife erzeugt. Den Switch Befehl habe ich auch im obj_invKnife, also kann man annehmen, dass obj_invKife.box = 1 ist, oder?

    Ich habe einen Befehl, mit dem ich bezwecken möchte, dass wenn mein obj_invKnife und mein obj_invScope diesselbe box (also box = 1) haben und man die Taste 1 drückt, mein obj_invKnife auf x = 88 und y = 40 "teleportiert" wird. Ich habe es sowohl mit instance_create als auch mit x = 88 und y = 40 probiert. Allerdings tut sich in beiden Fällen nichts. Was tun? :(

    GML-Quellcode

    1. if (box = obj_invScope.box)
    2. {
    3. if (keyboard_check_pressed(vk_numpad1))
    4. {
    5. instance_create(88, 40, obj_invKnife);
    6. }
    7. if (keyboard_check_pressed(vk_numpad2))
    8. {
    9. x = 188;
    10. y = 40;
    11. }
    12. }
    Alles anzeigen


    WICHTIGES UPDATE:

    Habe mal den string box ins draw event geschrieben, und obwohl mein obj_invScope über die einzelnen Felder wandert, bleibt der Wert bei 0? warum?
    Es gibt 10 Arten von Menschen: Diejenigen, die Binärcode verstehen und die, die es nicht tun ^^

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von CallMeLegend ()

  • Ich könnte mein Inventory system aus wwyd mal ausgraben, wenn du denn willst. Ist halt was umfangreicher. Ich habe da einmal die Hotbar als Sprite, mit 7 subimages (jedes mit einem Kasten um einen anderen Auswahlplatz), dann ein spritesheet welcher die item Icons enthält (werden in die hotbar gemalt) ein sprite für die Waffe/Item (mit einem outline Glow prebaked) wie sie in der Welt zum aufnehemen aussieht, dann noch finale animierte Sprites für die waffe in der Hand. Für jedes Item gibt es ein script (zB scr_ump45) welches Itemspezifische werte festlegt. Meine Hotbar besteht aus einem 2dimensionalen Array. Hier benutze ich einen Speziellen Syntax [i,0] = Name; [i,1] = Beschreibung; [i,2] = Icon Index; [i,3] = ScriptName (zugriff durch asset_get_index(ScriptName)); [i,4] = Zusatzwert, bei Waffen Schussanzahl. Diese Werte werden duch ein eigens entwickeltes Script dynamisch aus Dateien (zB. itm_5.dat) ausgelesen und können dann in ein beliebiges 2dimensionales Array eingelesen werden sofern es die obrige Struktur aufweist. Man kann damit also auch ganz leicht Kisten etc einbauen, in die Items abgelegt werden können. Falls du dir halbwegs was drunter vorstellen kannst gib mir bescheid, dann werde ich mich bemühen den Code aufzuarbeiten und hier reinzustellen

    EDIT:

    GML-Quellcode

    1. ///scr_hotbar_ini()
    2. hotkeySelected = 1; //starts with (1), (0) is used for default statement (blank hotbar)
    3. hotkeyLast = hotkeySelected;
    5. hotkeySelectedOld = hotkeySelected; //used for Text blending
    6. hotkeyAlpha = 1;
    9. for (i = 0; i <= 7; i++){
    10. global.hotkeySlot[i,0] = ""; //name
    11. global.hotkeySlot[i,1] = ""; //description
    12. global.hotkeySlot[i,2] = 0; //sprite index
    13. global.hotkeySlot[i,3] = "scr_none"; //script to execute
    14. global.hotkeySlot[i,4] = 0; //additional value
    15. }
    Alles anzeigen

    GML-Quellcode

    1. ///scr_hotbar_draw()
    2. draw_set_alpha(1);
    4. draw_set_font(fnt_sys1_small);
    5. draw_set_halign(fa_center);
    6. draw_set_valign(fa_middle);
    8. var _h1 = sprite_get_height(gui_selector);
    9. var _h2 = _h1 + sprite_get_height(spr_hotbar_cover);
    11. //Draw Selector
    12. draw_sprite(gui_selector, 0, round(global.ds_width/2), global.ds_height-_h1);
    14. //Draw Icons
    15. for (i = 0; i <= 7; i++) {
    16. if (global.hotkeySlot[i,0] != "") {
    18. draw_sprite(spr_icons, global.hotkeySlot[i,2],
    19. round(global.ds_width/2)-sprite_get_xoffset(gui_selector)+(i*80),global.ds_height-_h1);
    21. if (i+1 = hotkeySelected)
    22. {
    23. draw_set_alpha(hotkeyAlpha)
    25. draw_text_outlined(round(global.ds_width/2),
    26. global.ds_height - _h2 - 35, 2, string(global.hotkeySlot[i,0]), c_black,
    27. c_orange);
    28. draw_set_alpha(1);
    29. }
    30. }
    31. }
    33. draw_sprite(gui_selector,
    34. clamp(hotkeySelected,0,sprite_get_number(gui_selector)-1),
    35. round(global.ds_width/2), global.ds_height-_h1);
    36. draw_sprite(spr_hotbar_cover, 0, round(global.ds_width/2), global.ds_height-_h2);
    38. if (armed) {
    39. draw_set_valign(fa_top);
    40. /*
    41. if (gunReloadTimer != -1) {
    42. draw_text_outlined(round(global.ds_width/2),global.ds_height-_h2,2,"reloading...",c_black,c_yellow);
    43. }
    44. */
    46. if (global.hotkeySlot[hotkeyLast-1,4] != -1) {
    47. draw_set_halign(fa_left);
    50. draw_text_outlined(round(global.ds_width/2)-sprite_get_xoffset(gui_selector)
    51. + 10,global.ds_height-_h2,2,"Rounds: " +
    52. string(global.hotkeySlot[hotkeyLast-1,4]) + "x",c_black,c_orange);
    53. }
    54. draw_set_halign(fa_right);
    57. draw_text_outlined(round(global.ds_width/2)-sprite_get_xoffset(gui_selector)+sprite_get_width(gui_selector)
    58. -
    59. 10,global.ds_height-_h2,2,string(global.hotkeySlot[hotkeyLast-1,1]),c_black,c_orange);
    60. }
    62. draw_set_halign(fa_left);
    63. draw_set_valign(fa_top);
    Alles anzeigen

    GML-Quellcode

    1. ///scr_hotbar_left()
    2. hotkeySelected = max(1, hotkeySelected-1);
    3. audio_play_sound(snd_click_1, 10, false);

    GML-Quellcode

    1. ///scr_hotbar_right()
    2. hotkeySelected = min(8, hotkeySelected+1);
    3. audio_play_sound(snd_click_1, 10, false);

    GML-Quellcode

    1. ///scr_hotbar_step()
    2. if(hotkeySelected != hotkeySelectedOld)
    3. {
    4. hotkeyAlpha = 1;
    5. }else{
    6. hotkeyAlpha = max(0, hotkeyAlpha-0.01);
    7. }
    8. hotkeySelectedOld = hotkeySelected;
    10. if ((keyboard_check_pressed(vk_enter)|| mouse_check_button_pressed(mb_right)) &!global.show_console &!show_stats)
    11. {
    12. hotkeyLast = hotkeySelected;
    14. gunReloadTimer = -1;
    16. if (audio_is_playing(gunSoundID)) { //stop previous sound
    17. audio_stop_sound(gunSoundID);
    18. }
    20. if (script_exists(asset_get_index(global.hotkeySlot[hotkeySelected-1,3])))
    21. {
    22. script_execute(asset_get_index(global.hotkeySlot[hotkeySelected-1,3]));
    23. }
    24. }
    Alles anzeigen

    GML-Quellcode

    1. ///scr_hotbar_get_free()
    2. //returns pos / -1
    4. var _pos;
    5. _pos = 0;
    7. repeat(array_height_2d(global.hotkeySlot)) {
    8. if (global.hotkeySlot[_pos,0] = "") {
    9. return _pos;
    10. }
    11. _pos++
    12. }
    14. return -1;
    Alles anzeigen


    GML-Quellcode

    1. ///scr_item_add(array 2d,pos,id)
    3. var _array, _pos, _id;
    4. _array = argument0; //NOTE: ARRAY IS COPIED WHEN CHANGED // USE @ FOR DIRECT ACCESS INSTEAD
    5. _pos = argument1;
    6. _id = argument2;
    8. var _list = scr_get_item(_id);
    9. if (_list = -1) {
    10. scr_add_notification_ext("FAILED CATCHING ITEM LIST::ID_" + string(_id),c_red,1);
    11. exit;
    12. }
    14. _array[@ _pos,0] = string(ds_list_find_value(_list,0));
    15. _array[@ _pos,1] = string(ds_list_find_value(_list,1));
    16. _array[@ _pos,2] = real(ds_list_find_value(_list,2));
    17. _array[@ _pos,3] = string(ds_list_find_value(_list,3));
    18. _array[@ _pos,4] = real(ds_list_find_value(_list,4));
    20. ds_list_destroy(_list);
    Alles anzeigen

    GML-Quellcode

    1. ///scr_get_item(id)
    2. //returns ds_list
    4. var file = argument0;
    5. file = "itm_" + string(file) + ".dat";
    7. file = file_text_open_read(working_directory + "items\" + string(file));
    8. if (file = -1) {
    9. scr_add_notification_ext("FAILED LOADING::items\" + string(file),c_red,1);
    10. return -1;
    11. }
    13. var _list = ds_list_create();
    15. ds_list_add(_list,file_text_read_string(file));
    16. file_text_readln(file);
    17. ds_list_add(_list,file_text_read_string(file));
    18. file_text_readln(file);
    19. ds_list_add(_list,file_text_read_real(file));
    20. file_text_readln(file);
    21. ds_list_add(_list,file_text_read_string(file));
    22. file_text_readln(file);
    23. ds_list_add(_list,file_text_read_real(file));
    25. file_text_close(file);
    27. return _list;
    Alles anzeigen

    GML-Quellcode

    1. //weapon pickup (in par_item)
    2. var _pos;
    3. _pos = scr_hotbar_get_free();
    5. if (_pos = -1) {
    6. scr_add_notification("You are carrying too much!");
    7. exit;
    8. }else{
    9. scr_add_notification("Picked up " + string(ItemString) + "!");
    10. }
    12. scr_item_add(global.hotkeySlot,_pos,ID);
    14. if (global.itemAutoSelect) {
    15. with (obj_player) {
    16. hotkeySelected = _pos+1;
    17. hotkeyLast = hotkeySelected;
    18. hotkeySelectedOld = hotkeySelected;
    19. hotkeyAlpha = 1;
    20. if (script_exists(asset_get_index(global.hotkeySlot[hotkeySelected-1,3]))){
    21. script_execute(asset_get_index(global.hotkeySlot[hotkeySelected-1,3]));
    22. }
    23. }
    24. }
    26. instance_destroy();
    Alles anzeigen


    Du wirst es was abstrahieren müssen und ich gebe zu es ist eventuell ein wenig übers Ziel hinausgeschossen, aber wenn du die Grundmechanik verstehst ist es schon Gold wert. Wie du siehst braucht es mit dem 2d array keine extra InventarObjekte, und die scr_hotbar_get_free funktion macht genau das was du willst, nämlich das Item was man aufnimmt im nächst-freien Slot abzulegen. Das heißt auch das du keine spezifischen Slots erstellen musst.
    132 little bugs in the code. 132 little bugs. Fix a few, set the compiler to stew, 172 little bugs in the code... :vogel:

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von Rhazul ()